home *** CD-ROM | disk | FTP | other *** search
/ Floppyshop 2 / Floppyshop - 2.zip / Floppyshop - 2.iso / diskmags / 0022-3.564 / dmg-3419 / pack_snt.205 / dat_depa.s next >
Text File  |  1991-04-25  |  4KB  |  199 lines
  1. *
  2. * Depack routine voor data
  3. * 
  4. ***************************************
  5. * Sentry Packer v2.01 Data Decruncher *
  6. * Coded by Eagle. (20 Jan 1992)       *
  7. * Source a0, d0: length packed data   *
  8. * OUT: D0=depacked length          *
  9. ***************************************
  10.  
  11.     lea     data(pc),a0    ; source
  12.     lea     buf(pc),a1    ; dest
  13.     move.l    #buf-data,d0    ; lengte packed data
  14.     bsr    sentry2
  15.  
  16. sentry2    lea    (a1),a3
  17.     lea    (a0,d0.l),a0
  18.     tst.b    -1(a0)
  19.     bne.s    .cont1
  20.     subq.l    #1,a0
  21. .cont1    moveq    #8,d6
  22.     bsr    get_long1
  23.     cmpi.l    #'2tnS',d0    ; Snt2
  24.     beq.s    .unpack
  25.     rts
  26. .unpack    bsr    get_long1
  27.     lea    (a3,d0.l),a2    ; dest adres
  28.     move.l    d0,-(sp)
  29.     move.l    a2,a5        ; save for picture depack
  30.     bsr    get_long1
  31.     moveq    #0,d1
  32.     bsr    .getbyte
  33.     move.w    d2,unp_pic
  34.     moveq    #0,d1
  35.     bsr    .getbyte
  36.     move.w    d2,unp_sam
  37.     bne.s    .no_sam
  38.     move.l    d0,-(sp)
  39.     bsr    get_long1
  40.     move.l    d0,samoff1+4
  41.     bsr    get_long1
  42.     move.l    d0,samoff1
  43.     move.l    (sp)+,d0
  44. .no_sam    bsr.s    .unp_loop    ; unpack data
  45.     tst    unp_pic
  46.     bne.s    .no_pic
  47.     bsr    unp_picture
  48. .no_pic    tst    unp_sam
  49.     bne.s    .no_mod
  50.     bsr    samples
  51. .no_mod    move.l    (sp)+,d0
  52.     rts
  53.  
  54. .unp_loop
  55.     bsr.s    .getbit
  56. .cont    bcs.s   .blocks
  57.     bsr.s    .getbit
  58.     bcs.s    .copy_2
  59.     move.b    -(a0),-(a2)    ; 1 byte copy
  60.     bra    .l_col
  61. .copy_2    bsr.s    .getbit
  62.     bcs.s    .c_more
  63.     moveq    #1,d2        ; copy 2 bytes
  64.     bra.s    .copy
  65. .c_more    lea    copy_tab1(pc),a4
  66. .c_loop    move.l    (a4)+,d1
  67.     bsr.s    .getbyte        ; haal aantal
  68.     subq.w    #1,d2
  69.     bpl.s    .found
  70.     bra.s    .c_loop
  71. .found    swap    d1
  72.     add.w    d1,d2
  73.  
  74. .copy    move.b    -(a0),-(a2)
  75.     dbf    d2,.copy
  76.     bra    .l_col
  77.  
  78. .get_off
  79.     MOVEQ    #1,D1        ;OFFSET
  80.     BSR.S    .getbyte
  81.     move.b    (a4,d2),d1    ; bits
  82.     ADD.W    D2,D2
  83.     ext.w    d1
  84.     move.w    4(a4,d2),d4
  85.     bsr.s    .getbyte
  86.     add.w    d4,d2
  87.     rts
  88. .getbit    add.l    d0,d0    ;LSR.L    #1,D0
  89.     beq.s    .haha
  90.     rts
  91. .haha    bsr.s    get_long1
  92.     addx.l    d0,d0    ;ROXR.L  #1,D0
  93.     rts
  94. .haha1    bsr.s    get_long1
  95.     addx.l    d0,d0    ;ROXR.L  #1,D0
  96.     bra.s    .getbyt
  97. .getbyte
  98.     CLR.W   D2
  99. .loop    add.l    d0,d0    ;LSR.L    #1,D0
  100.     beq.s    .haha1
  101. .getbyt    addx.L  d2,D2 
  102.     DBF     D1,.loop
  103.     RTS
  104.  
  105. .blocks    bsr.s    .getbit
  106.     bcs.s    .string3
  107.     moveq    #1,d3        ; 2 bytes-string
  108.     moveq    #8-1,d1    ; small-bits-offset
  109.     bra.s    .string_copy
  110. .string3
  111.     lea    small_offset1(pc),a4
  112.     bsr.s    .getbit
  113.     bcs.s    .string_more
  114.     moveq    #2,d3        ; 3 bytes-string
  115.     bra.s    .do_strings
  116. .string_more
  117.     moveq    #1,d1        ; 2 bits-commando
  118.     bsr.s    .getbyte
  119.     subq.w    #1,d2        ; large string?
  120.     bmi.s    .large
  121.     moveq    #3,d3        ; minimaal 4 bytes-string
  122.     add.w    d2,d3        ; meer?
  123.     bra.s    .do_strings
  124. .large    lea    aantal_tab1(pc),a4
  125.     bsr.s    .get_off
  126.     move.w    d2,d3
  127.     lea    offset_tab1(pc),a4
  128. .do_strings
  129.     bsr.s    .get_off
  130.     bra.s    .s_copy
  131. .string_copy
  132.     bsr.s    .getbyte
  133. .s_copy    move.b    -1(a2,d2.w),-(a2) 
  134.     dbf    d3,.s_copy
  135.  
  136. .l_col    cmpa.l    a2,a3 
  137.     blt    .unp_loop
  138.     RTS
  139. get_long1
  140.     move.b    -(a0),d0
  141.     lsl.l    d6,d0
  142.     move.b    -(a0),d0
  143.     lsl.l    d6,d0
  144.     move.b    -(a0),d0
  145.     lsl.l    d6,d0
  146.     move.b    -(a0),d0
  147.     move.w    #$10,ccr
  148.     rts
  149. samples    lea    samoff1(pc),a1
  150.     move.l    a3,a0        ; source adres
  151.     add.l    (a1)+,a0
  152.     move.l    (a1),d0
  153.     lea    (a0,d0.l),a2
  154. .loop    move.b    (a0)+,d0
  155.     sub.b    d0,(a0)
  156.     neg.b    (a0)
  157.     cmp.l    a2,a0
  158.     blt.s    .loop
  159.     rts
  160. unp_picture
  161. .low    move.w    #$0f9f,d7
  162. snt2_01    moveq    #3,d6
  163. snt2_02    move.w    -(a5),d4
  164.     moveq    #3,d5
  165. snt2_03    add.w    d4,d4
  166.     addx.w    d0,d0
  167.     add.w    d4,d4
  168.     addx.w    d1,d1
  169.     add.w    d4,d4
  170.     addx.w    d2,d2
  171.     add.w    d4,d4
  172.     addx.w    d3,d3
  173.     dbra    d5,snt2_03
  174.     dbra    d6,snt2_02
  175.     movem.w d0-d3,(a5)
  176.     dbra    d7,snt2_01
  177.     rts
  178. samoff1    dc.l    0,0
  179. unp_pic    dc.w    0
  180. unp_sam    dc.w    0
  181. offset_tab1
  182.     dc.b    5-1,8-1,9-1,13-1
  183.     dc.w    1,1+32,1+32+256,1+32+256+512
  184. aantal_tab1
  185.     dc.b    2-1,3-1,5-1,9-1
  186.     dc.w    6,6+4,6+4+8,6+4+8+32
  187. small_offset1
  188.     dc.b    4-1,5-1,7-1,9-1
  189.     dc.w    1,1+16,1+16+32,1+16+32+128
  190. copy_tab1
  191.     dc.w    2,1
  192.     dc.w    5,2
  193.     dc.w    12,3
  194.     dc.w    27,4
  195.  
  196. data    incbin    blb_*.s
  197.  
  198. buf    ds.l    10000
  199.